Added alias expansion and fixed README

Set PATH variables to allow gems such as Bundler to be found and for the
`ruby-info` function to properly work.

A default Ruby must be set in ~/.ruby-version; for more information, see
https://github.com/postmodern/chruby#default-ruby.

Signed-off-by: Sorin Ionescu <sorin.ionescu@gmail.com>

.gitmodules

@@ -7,3 +7,12 @@
 [submodule "modules/completion/external"]
 	path = modules/completion/external
 	url = https://github.com/zsh-users/zsh-completions.git
+[submodule "modules/prompt/external/powerline"]
+	path = modules/prompt/external/powerline
+	url = https://github.com/davidjrice/prezto_powerline.git
+[submodule "modules/prompt/external/agnoster"]
+	path = modules/prompt/external/agnoster
+	url = https://gist.github.com/3712874.git
+[submodule "modules/prompt/functions/pure"]
+	path = modules/prompt/external/pure
+	url = https://github.com/sindresorhus/pure.git

README.md

@@ -107,7 +107,7 @@ OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
 SOFTWARE.
 
 [1]: http://www.zsh.org
-[2]: http://i.imgur.com/nBEEZ.png "sorin theme"
+[2]: http://i.imgur.com/AzjmpwM.png "sorin theme"
 [3]: http://git-scm.com
 [4]: https://github.com
 [5]: http://gitimmersion.com

modules/explainshell/README.md

@@ -0,0 +1,11 @@
+#Explainshell
+
+Adds a keybinding and a function to open 
+[explainshell.com](http://www.explainshell.com) with the content of the command
+line.
+
+##Settings
+###Key-Binding
+The keybinding to open [explainshell.com](http://www.explainshell.com)
+
+`zstyle ':prezto:module:explainshell' key-binding '^K'`

modules/explainshell/init.zsh

@@ -0,0 +1,63 @@
+#
+# Adds a explain function and explainshell widget
+# 
+# Authors
+#   C Lentfort
+#
+
+function _expand_alias_recursive {
+  local _alias
+  for word in "$@"; do
+    # Check if word is aliased
+    _alias=$aliases[$word]
+    if [ -n "$_alias" ]; then
+      # Check if found alias and given command are identical
+      if [[ "$_alias" != "${(j: :)@}" ]]; then
+        _expand_alias_recursive "${(z)_alias}"
+      else
+        _explainshell_expanded_buffer+=$1
+      fi
+    else
+      _explainshell_expanded_buffer+=$word
+    fi
+  done
+}
+
+function explain {
+  local url
+  # We don't explain empty buffers
+  if (( $# == 0 )); then
+    return 1;
+  fi
+
+  # Replace aliases with their actual expansions
+  _explainshell_expanded_buffer=()
+  _expand_alias_recursive $@
+  _explainshell_expanded_buffer=(${(u)_explainshell_expanded_buffer})
+  # base url with first command already injected
+  # $ explain tar
+  #   => http://explainshel.com/explain/tar?args=
+  url="http://explainshell.com/explain?cmd="
+
+  # iterates over remaining args and adds builds the rest of the url
+  for i in "$_explainshell_expanded_buffer"; do
+    url=$url"$i""+"
+  done
+
+  unset _explainshell_expanded_buffer
+  # opens url in browser
+  $BROWSER -t $url &> /dev/null
+}
+
+function explainshell {
+  explain ${(z)BUFFER}
+}
+
+zle -N explainshell
+
+zstyle -s ':prezto:module:explainshell' key-binding 'key_binding'
+if [[ -n "$key_binding" ]]; then
+  bindkey "$key_binding" explainshell
+fi
+
+unset key_binding

modules/prompt/functions/prompt_agnoster_setup

@@ -0,0 +1 @@
+../external/agnoster/agnoster.zsh-theme

modules/prompt/functions/prompt_cloud_setup

@@ -0,0 +1,121 @@
+#
+# A minimal two-color theme.
+#
+# Authors:
+#   Kevin Laude <nerfyoda@gmail.com>
+#
+# Features:
+#   - One line, left aligned.
+#   - The prompt is prefixed by a character sequence of your choice.
+#   - Only displays the current directory instead of the full path.
+#   - Displays the current branch when in a git project (this requires loading
+#     the git module before prompt in ~/.zpreztorc).
+#   - Displays a character at the end of the prompt when in a git project with
+#     "dirty" files.
+#
+# Usage:
+#   This prompt's prefix symbol and colors are customizable:
+#     prompt cloud [<symbol>] [<color1>] [<color2>]
+#
+#   In ~/.zpreztorc:
+#     zstyle ':prezto:module:prompt' theme 'cloud' \
+#       ['<symbol>'] \
+#       ['<color1>'] \
+#       ['<color2>']
+#
+#   If these options are not provided, the symbol defaults to "☁" with colors
+#   cyan and green.
+#
+# Screenshots:
+#   http://i.imgur.com/mJCZ8rE.png
+#
+# Note:
+#   This is a port of the oh-my-zsh cloud theme, originally written by Phillip
+#   Ridlen <p@rdln.net> and Mark Drago <markdrago@gmail.com>
+#
+
+# Load dependencies.
+pmodload 'helper'
+
+function prompt_cloud_precmd {
+  setopt LOCAL_OPTIONS
+  unsetopt XTRACE KSH_ARRAYS
+
+  # Get Git repository information.
+  if (( $+functions[git-info] )); then
+      git-info
+  fi
+}
+
+function prompt_cloud_help {
+  cat <<EOT
+This prompt's prefix symbol and colors are customizable:
+
+  prompt cloud [<symbol>] [<color1>] [<color2>]
+
+In ~/.zpreztorc:
+  zstyle ':prezto:module:prompt' theme 'cloud' ['<symbol>'] ['<color1>'] ['<color2>']
+
+If these options are not provided, the symbol defaults to ☁ with colors cyan
+and green.
+EOT
+}
+
+function prompt_cloud_preview {
+  if (( $# > 0 )); then
+    prompt_preview_theme 'cloud' "$@"
+  else
+    prompt_preview_theme 'cloud'
+    print
+    prompt_preview_theme 'cloud' "✯"
+    print
+    prompt_preview_theme 'cloud' ">" "yellow" "red"
+  fi
+}
+
+function prompt_cloud_setup {
+  setopt LOCAL_OPTIONS
+  unsetopt XTRACE KSH_ARRAYS
+  prompt_opts=(cr percent subst)
+
+  # Set the theme prefix to a cloud or to the user's given characters.
+  if [[ -n "$1" ]]; then
+    prefix="$1"
+  else
+    prefix='☁'
+  fi
+
+  # Assign colors.
+  if [[ -n "$2" ]]; then
+    primary_color="$2"
+  else
+    primary_color='cyan'
+  fi
+
+  if [[ -n "$3" ]]; then
+    secondary_color="$3"
+  else
+    secondary_color='green'
+  fi
+
+  # Load required functions.
+  autoload -Uz add-zsh-hook
+
+  # Add hook for calling git-info before each command.
+  add-zsh-hook precmd prompt_cloud_precmd
+
+  # Set git-info parameters.
+  zstyle ':prezto:module:git:info' verbose 'yes'
+  zstyle ':prezto:module:git:info:dirty' format "%%B%F{$secondary_color}]%f%%b %F{yellow}⚡%f"
+  zstyle ':prezto:module:git:info:clean' format "%B%F{$secondary_color}]%f%b"
+  zstyle ':prezto:module:git:info:branch' format "%%B%F{$secondary_color}[%f%%b%%B%F{$primary_color}%b%f%%b"
+  zstyle ':prezto:module:git:info:keys' format \
+    'prompt' '%b%C%D' \
+    'rprompt' ''
+
+  # Define prompts.
+  PROMPT='%B%F{$primary_color}${prefix}%f%b  %B%F{$secondary_color}%c%f%b $git_info[prompt] '
+  RPROMPT=''
+}
+
+prompt_cloud_setup "$@"

modules/prompt/functions/prompt_damoekri_setup

@@ -0,0 +1,76 @@
+#
+# A simple theme inspired by the Sorin and PeepCode themes.
+#
+# Authors:
+#   Daniel Møller Kristensen <damoekri@icloud.com>
+#
+# Screenshots:
+#   http://i.imgur.com/AX9HnPF.png
+#
+
+# Load dependencies.
+pmodload 'helper'
+
+function prompt_damoekri_pwd {
+  local pwd="${PWD/#$HOME/~}"
+
+  if [[ "$pwd" == (#m)[/~] ]]; then
+    _prompt_damoekri_pwd="$MATCH"
+    unset MATCH
+  else
+    _prompt_damoekri_pwd="${${${${(@j:/:M)${(@s:/:)pwd}##.#?}:h}%/}//\%/%%}/${${pwd:t}//\%/%%}"
+  fi
+}
+
+function prompt_damoekri_precmd {
+  setopt LOCAL_OPTIONS
+  unsetopt XTRACE KSH_ARRAYS
+
+  # Format PWD.
+  prompt_damoekri_pwd
+
+  # Get Git repository information.
+  if (( $+functions[git-info] )); then
+    git-info
+  fi
+
+  # Get Ruby version information.
+  if (( $+functions[ruby-info] )); then
+    ruby-info
+  fi
+}
+
+function prompt_damoekri_setup {
+  setopt LOCAL_OPTIONS
+  unsetopt XTRACE KSH_ARRAYS
+  prompt_opts=(cr percent subst)
+
+  # Load required functions.
+  autoload -Uz add-zsh-hook
+
+  # Add hook for calling git-info and ruby-info before each command.
+  add-zsh-hook precmd prompt_damoekri_precmd
+
+  # Set editor-info parameters.
+  zstyle ':prezto:module:editor:info:keymap:primary' format ' %F{green}»%f'
+
+  # Set git-info parameters.
+  zstyle ':prezto:module:git:info' verbose 'yes'
+  zstyle ':prezto:module:git:info:action' format ':%F{magenta}%s%f'
+  zstyle ':prezto:module:git:info:branch' format '%F{blue}%b%f'
+  zstyle ':prezto:module:git:info:clean' format ' %F{green}✔%f'
+  zstyle ':prezto:module:git:info:dirty' format ' %F{red}✗%f'
+  zstyle ':prezto:module:git:info:commit' format '%F{blue}%.7c%f'
+  zstyle ':prezto:module:git:info:position' format '%F{blue}%p%f'
+  zstyle ':prezto:module:git:info:keys' format \
+    'rprompt' ' $(coalesce "%b" "%p" "%c")%s%C%D'
+
+  # Set ruby-info parameters.
+  zstyle ':prezto:module:ruby:info:version' format ' %F{yellow}%v%f'
+
+  # Define prompts.
+  PROMPT='%F{cyan}${_prompt_damoekri_pwd}%f${editor_info[keymap]} '
+  RPROMPT='${git_info:+${(e)git_info[rprompt]}}${ruby_info:+${ruby_info[version]}}'
+}
+
+prompt_damoekri_setup "$@"

modules/prompt/functions/prompt_giddie_setup

@@ -0,0 +1,76 @@
+#
+# A colorful, friendly, multiline theme with some handy features.
+#
+# Authors:
+#   Paul Gideon Dann <pdgiddie@gmail.com>
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+# Features:
+#   - Simple VCS branch, staged, and unstaged indication.
+#   - Prompt character is different in a VCS repository.
+#   - Last command exit status is displayed when non-zero.
+#
+# Screenshots:
+#   http://i.imgur.com/rCo3S.png
+#
+
+function +vi-set_novcs_prompt_symbol {
+  _prompt_giddie_symbol=')'
+}
+
+function +vi-set_vcs_prompt_symbol {
+  _prompt_giddie_symbol='±'
+}
+
+function +vi-git_precmd {
+  # Check for untracked files, since vcs_info does not.
+  if [[ -n $(git ls-files --other --exclude-standard 2> /dev/null) ]]; then
+    hook_com[unstaged]+='%F{green}?%f'
+  fi
+}
+
+function prompt_giddie_precmd {
+  # Replace '/home/<user>' with '~'.
+  _prompt_giddie_pwd="${PWD/#$HOME/~}"
+  vcs_info
+}
+
+function prompt_giddie_setup {
+  setopt LOCAL_OPTIONS
+  unsetopt XTRACE KSH_ARRAYS
+  prompt_opts=(cr percent subst)
+
+  # Load required functions.
+  autoload -Uz vcs_info
+  autoload -Uz add-zsh-hook
+
+  # Add hook to set up prompt parameters before each command.
+  add-zsh-hook precmd prompt_giddie_precmd
+
+  # Set editor-info parameters.
+  zstyle ':prezto:module:editor:info:completing' format '%F{green}...%f'
+  zstyle ':prezto:module:editor:info:keymap:alternate' format '%F{yellow}--- COMMAND ---%f'
+
+  # Set vcs_info parameters.
+  zstyle ':vcs_info:*' check-for-changes true
+  zstyle ':vcs_info:*' formats ' on %F{magenta}%b%f%c%u'
+  zstyle ':vcs_info:*' actionformats ' on %F{magenta}%b%f%c%u %F{yellow}(%a)%f'
+  zstyle ':vcs_info:*' stagedstr '%F{green}+%f'
+  zstyle ':vcs_info:*' unstagedstr '%F{green}!%f'
+
+  # Set vcs_info hooks.
+  # NOTE: Prior to Zsh v4.3.12, there are no static hooks, no vcs_info_hookadd
+  #       function, and no 'no-vcs' hook.
+  zstyle ':vcs_info:*+start-up:*' hooks set_novcs_prompt_symbol
+  zstyle ':vcs_info:git*+set-message:*' hooks set_vcs_prompt_symbol git_precmd
+  zstyle ':vcs_info:*+set-message:*' hooks set_vcs_prompt_symbol
+
+  # Define prompts.
+  PROMPT='%(?..%F{red}%B-> [%?]%b%f
+)%F{magenta}%n%f@%F{yellow}%m%f|%F{green}${_prompt_giddie_pwd}%f${vcs_info_msg_0_}
+%F{blue}${_prompt_giddie_symbol}%f '
+  RPROMPT='${editor_info[keymap]}'
+  SPROMPT='zsh: correct %F{magenta}%R%f to %F{green}%r%f [nyae]? '
+}
+
+prompt_giddie_setup "$@"

modules/prompt/functions/prompt_kylewest_setup

@@ -0,0 +1,65 @@
+#
+# A single line theme with Git information on the left and Ruby on the right.
+#
+# Authors:
+#   Kyle West <kswest@gmail.com>
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+# Features:
+#   - Indicates dirty Git repository.
+#   - Indicates the Ruby version.
+#   - Indicates vi modes.
+#
+# Screenshots:
+#   http://i.imgur.com/dCwhynn.png
+#
+
+function prompt_kylewest_precmd {
+  setopt LOCAL_OPTIONS
+  unsetopt XTRACE KSH_ARRAYS
+
+  # Get Git repository information.
+  if (( $+functions[git-info] )); then
+    git-info
+  fi
+
+  # Get Ruby information.
+  if (( $+functions[ruby-info] )); then
+    ruby-info
+  fi
+}
+
+function prompt_kylewest_setup {
+  setopt LOCAL_OPTIONS
+  unsetopt XTRACE KSH_ARRAYS
+  prompt_opts=(cr percent subst)
+
+  # Load required functions.
+  autoload -Uz add-zsh-hook
+
+  # Add hook for calling git-info before each command.
+  add-zsh-hook precmd prompt_kylewest_precmd
+
+  # Set editor-info parameters.
+  zstyle ':prezto:module:editor:info:completing' format '%B%F{red}...%f%b'
+  zstyle ':prezto:module:editor:info:keymap:primary' format "%B%F{green}❯%f%b"
+  zstyle ':prezto:module:editor:info:keymap:alternate' format "%B%F{magenta}❮%f%b"
+
+  # Set git-info parameters.
+  zstyle ':prezto:module:git:info' verbose 'no'
+  zstyle ':prezto:module:git:info:branch' format '%F{yellow}%b%f'
+  zstyle ':prezto:module:git:info:dirty' format '%B%F{red}!%f%b'
+  zstyle ':prezto:module:git:info:indexed' format ' '
+  zstyle ':prezto:module:git:info:unindexed' format ' '
+  zstyle ':prezto:module:git:info:untracked' format ' '
+  zstyle ':prezto:module:git:info:keys' format 'prompt' '- %b%D '
+
+  # Set ruby-info parameters.
+  zstyle ':prezto:module:ruby:info:version' format '%F{blue}[%v]%f'
+
+  # Define prompts.
+  PROMPT='%F{cyan}%c%f ${git_info[prompt]}${editor_info[keymap]} '
+  RPROMPT='${ruby_info[version]}'
+}
+
+prompt_kylewest_setup "$@"

modules/prompt/functions/prompt_minimal_setup

@@ -9,7 +9,7 @@
 #   http://i.imgur.com/zLZNK.png
 #
 
-function +vi-git-status() {
+function +vi-git_status {
   # Check for untracked files or updated submodules since vcs_info does not.
   if [[ -n $(git ls-files --other --exclude-standard 2> /dev/null) ]]; then
     hook_com[unstaged]='%F{red}●%f'
@@ -40,7 +40,7 @@ function prompt_minimal_setup {
   zstyle ':vcs_info:*' formats ' - [%b%c%u]'
   zstyle ':vcs_info:*' actionformats " - [%b%c%u|%F{cyan}%a%f]"
   zstyle ':vcs_info:(sv[nk]|bzr):*' branchformat '%b|%F{cyan}%r%f'
-  zstyle ':vcs_info:git*+set-message:*' hooks git-status
+  zstyle ':vcs_info:git*+set-message:*' hooks git_status
 
   # Define prompts.
   PROMPT='%2~${vcs_info_msg_0_} » '

modules/prompt/functions/prompt_paradox_setup

@@ -0,0 +1,154 @@
+#
+# A two-line, Powerline-inspired theme that displays contextual information.
+#
+# This theme requires a patched Powerline font, get them from
+# https://github.com/Lokaltog/powerline-fonts.
+#
+# Authors:
+#   Isaac Wolkerstorfer <i@agnoster.net>
+#   Jeff Sandberg <paradox460@gmail.com>
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#
+# Screenshots:
+#   http://i.imgur.com/0XIWX.png
+#
+
+# Load dependencies.
+pmodload 'helper'
+
+# Define variables.
+_prompt_paradox_current_bg='NONE'
+_prompt_paradox_segment_separator='⮀'
+_prompt_paradox_start_time=$SECONDS
+
+function prompt_paradox_start_segment {
+  local bg fg
+  [[ -n "$1" ]] && bg="%K{$1}" || bg="%k"
+  [[ -n "$2" ]] && fg="%F{$2}" || fg="%f"
+  if [[ "$_prompt_paradox_current_bg" != 'NONE' && "$1" != "$_prompt_paradox_current_bg" ]]; then
+    print -n " $bg%F{$_prompt_paradox_current_bg}$_prompt_paradox_segment_separator$fg "
+  else
+    print -n "$bg$fg "
+  fi
+  _prompt_paradox_current_bg="$1"
+  [[ -n "$3" ]] && print -n "$3"
+}
+
+function prompt_paradox_end_segment {
+  if [[ -n "$_prompt_paradox_current_bg" ]]; then
+    print -n " %k%F{$_prompt_paradox_current_bg}$_prompt_paradox_segment_separator"
+  else
+    print -n "%k"
+  fi
+  print -n "%f"
+  _prompt_paradox_current_bg=''
+}
+
+function prompt_paradox_build_prompt {
+  prompt_paradox_start_segment black default '%(?::%F{red}✘ )%(!:%F{yellow}⚡ :)%(1j:%F{cyan}⚙ :)%F{blue}%n%F{red}@%F{green}%m%f'
+  prompt_paradox_start_segment blue black '$_prompt_paradox_pwd'
+
+  if [[ -n "$git_info" ]]; then
+    prompt_paradox_start_segment green black '${(e)git_info[ref]}${(e)git_info[status]}'
+  fi
+
+  prompt_paradox_end_segment
+}
+
+function prompt_paradox_pwd {
+  local pwd="${PWD/#$HOME/~}"
+
+  if [[ "$pwd" == (#m)[/~] ]]; then
+    _prompt_paradox_pwd="$MATCH"
+    unset MATCH
+  else
+    _prompt_paradox_pwd="${${${${(@j:/:M)${(@s:/:)pwd}##.#?}:h}%/}//\%/%%}/${${pwd:t}//\%/%%}"
+  fi
+}
+
+function prompt_paradox_print_elapsed_time {
+  local end_time=$(( SECONDS - _prompt_paradox_start_time ))
+  local hours minutes seconds remainder
+
+  if (( end_time >= 3600 )); then
+    hours=$(( end_time / 3600 ))
+    remainder=$(( end_time % 3600 ))
+    minutes=$(( remainder / 60 ))
+    seconds=$(( remainder % 60 ))
+    print -P "%B%F{red}>>> elapsed time ${hours}h${minutes}m${seconds}s%b"
+  elif (( end_time >= 60 )); then
+    minutes=$(( end_time / 60 ))
+    seconds=$(( end_time % 60 ))
+    print -P "%B%F{yellow}>>> elapsed time ${minutes}m${seconds}s%b"
+  elif (( end_time > 10 )); then
+    print -P "%B%F{green}>>> elapsed time ${end_time}s%b"
+  fi
+}
+
+function prompt_paradox_precmd {
+  setopt LOCAL_OPTIONS
+  unsetopt XTRACE KSH_ARRAYS
+
+  # Format PWD.
+  prompt_paradox_pwd
+
+  # Get Git repository information.
+  if (( $+functions[git-info] )); then
+    git-info
+  fi
+
+  # Calculate and print the elapsed time.
+  prompt_paradox_print_elapsed_time
+}
+
+function prompt_paradox_preexec {
+  _prompt_paradox_start_time="$SECONDS"
+}
+
+function prompt_paradox_setup {
+  setopt LOCAL_OPTIONS
+  unsetopt XTRACE KSH_ARRAYS
+  prompt_opts=(cr percent subst)
+
+  # Load required functions.
+  autoload -Uz add-zsh-hook
+
+  # Add hook for calling git-info before each command.
+  add-zsh-hook preexec prompt_paradox_preexec
+  add-zsh-hook precmd prompt_paradox_precmd
+
+  # Set editor-info parameters.
+  zstyle ':prezto:module:editor:info:completing' format '%B%F{red}...%f%b'
+  zstyle ':prezto:module:editor:info:keymap:primary' format '%B%F{blue}❯%f%b'
+  zstyle ':prezto:module:editor:info:keymap:primary:overwrite' format '%F{red}♺%f'
+  zstyle ':prezto:module:editor:info:keymap:alternate' format '%B%F{red}❮%f%b'
+
+  # Set git-info parameters.
+  zstyle ':prezto:module:git:info' verbose 'yes'
+  zstyle ':prezto:module:git:info:action' format ' ⁝ %s'
+  zstyle ':prezto:module:git:info:added' format ' ✚'
+  zstyle ':prezto:module:git:info:ahead' format ' ⬆'
+  zstyle ':prezto:module:git:info:behind' format ' ⬇'
+  zstyle ':prezto:module:git:info:branch' format '⭠ %b'
+  zstyle ':prezto:module:git:info:commit' format '➦ %.7c'
+  zstyle ':prezto:module:git:info:deleted' format ' ✖'
+  zstyle ':prezto:module:git:info:dirty' format ' ⁝'
+  zstyle ':prezto:module:git:info:modified' format ' ✱'
+  zstyle ':prezto:module:git:info:position' format '%p'
+  zstyle ':prezto:module:git:info:renamed' format ' ➙'
+  zstyle ':prezto:module:git:info:stashed' format ' S'
+  zstyle ':prezto:module:git:info:unmerged' format ' ═'
+  zstyle ':prezto:module:git:info:untracked' format ' ?'
+  zstyle ':prezto:module:git:info:keys' format \
+    'ref' '$(coalesce "%b" "%p" "%c")' \
+    'status' '%s%D%A%B%S%a%d%m%r%U%u'
+
+  # Define prompts.
+  PROMPT='
+${(e)$(prompt_paradox_build_prompt)}
+ ${editor_info[keymap]} '
+  RPROMPT='%F{blue}[%F{green}%D{%H:%M:%S}%F{blue}]%f'
+  SPROMPT='zsh: correct %F{red}%R%f to %F{green}%r%f [nyae]? '
+}
+
+prompt_paradox_setup "$@"

modules/prompt/functions/prompt_peepcode_setup

@@ -10,16 +10,13 @@
 #   http://i.imgur.com/LhgmW.png
 #
 
-function +vi-git-status() {
-  # Check for untracked files or updated submodules since vcs_info does not.
-  if [[ -n $(git ls-files --other --exclude-standard 2> /dev/null) ]]; then
-    hook_com[unstaged]=' %F{8}✗%f'
-  fi
-}
-
 function prompt_peepcode_precmd {
-  vcs_info
+  # Get Git repository information.
+  if (( $+functions[git-info] )); then
+    git-info
+  fi
 
+  # Get Ruby information.
   if (( $+functions[ruby-info] )); then
     ruby-info
   fi
@@ -34,18 +31,19 @@ function prompt_peepcode_setup {
   autoload -Uz add-zsh-hook
   autoload -Uz vcs_info
 
-  # Add hook for calling vcs_info before each command.
+  # Add a hook for calling info functions before each command.
   add-zsh-hook precmd prompt_peepcode_precmd
 
-  # Set vcs_info parameters.
+  # Set git-info parameters.
-  zstyle ':vcs_info:*' enable git
+  zstyle ':prezto:module:git:info' verbose 'no'
-  zstyle ':vcs_info:*' check-for-changes true
+  zstyle ':prezto:module:git:info:action' format ' +%s'
-  zstyle ':vcs_info:*' get-revision true
+  zstyle ':prezto:module:git:info:branch' format ' %F{8}%b%f'
-  zstyle ':vcs_info:*' use-simple true
+  zstyle ':prezto:module:git:info:commit' format ' %F{white}%.7c%f'
-  zstyle ':vcs_info:*' unstagedstr ' %F{8}✗%f'
+  zstyle ':prezto:module:git:info:indexed' format ' '
-  zstyle ':vcs_info:*' formats ' %F{8}%b%f %F{white}%.7i%f%u'
+  zstyle ':prezto:module:git:info:unindexed' format ' '
-  zstyle ':vcs_info:*' actionformats ' %F{8}%b%f %F{white}%.7i%f +%a%u'
+  zstyle ':prezto:module:git:info:untracked' format ' '
-  zstyle ':vcs_info:git*+set-message:*' hooks git-status
+  zstyle ':prezto:module:git:info:dirty' format ' %F{8}✗%f'
+  zstyle ':prezto:module:git:info:keys' format 'rprompt' '%b%c%s%D'
 
   # Set ruby-info parameters.
   zstyle ':prezto:module:ruby:info:version' format ' %F{white}%v%f'
@@ -54,7 +52,7 @@ function prompt_peepcode_setup {
   PROMPT="
 %~
 %(?.%F{green}${1:-☻ }%f.%F{red}${1:-☻ }%f) "
-RPROMPT='${ruby_info[version]}${vcs_info_msg_0_}'
+RPROMPT='${ruby_info[version]}${git_info[rprompt]}'
 
 }
 

modules/prompt/functions/prompt_powerline_setup

@@ -0,0 +1 @@
+../external/powerline/prompt_powerline_setup

modules/prompt/functions/prompt_pure_setup

@@ -0,0 +1 @@
+../external/pure/pure.zsh

modules/prompt/functions/prompt_skwp_setup

@@ -0,0 +1,75 @@
+#
+# A single line theme with Git information on the left and Ruby on the right.
+#
+# Authors:
+#   Steve Losh <steve@stevelosh.com>
+#   Bart Trojanowski <bart@jukie.net>
+#   Brian Carper <brian@carper.ca>
+#   steeef <steeef@gmail.com>
+#   Sorin Ionescu <sorin.ionescu@gmail.com>
+#   Yan Pritzker <yan@pritzker.ws>
+#
+# Screenshots:
+#   http://i.imgur.com/gLgVp6Y.png
+#
+
+function prompt_skwp_precmd {
+  # Get Git repository information.
+  if (( $+functions[git-info] )); then
+    git-info
+  fi
+
+  # Get Ruby information.
+  if (( $+functions[ruby-info] )); then
+    ruby-info
+  fi
+}
+
+function prompt_skwp_setup {
+  setopt LOCAL_OPTIONS
+  unsetopt XTRACE KSH_ARRAYS
+  prompt_opts=(cr percent subst)
+
+  # Load required functions.
+  autoload -Uz add-zsh-hook
+
+  # Add hook to set up prompt parameters before each command.
+  add-zsh-hook precmd prompt_skwp_precmd
+
+  # Use extended color pallete if available.
+  if [[ $TERM = *256color* || $TERM = *rxvt* ]]; then
+    _prompt_skwp_colors=(
+      "%F{81}"  # Turquoise
+      "%F{166}" # Orange
+      "%F{135}" # Purple
+      "%F{161}" # Hotpink
+      "%F{118}" # Limegreen
+    )
+  else
+    _prompt_skwp_colors=(
+      "%F{cyan}"
+      "%F{yellow}"
+      "%F{magenta}"
+      "%F{red}"
+      "%F{green}"
+    )
+  fi
+
+  # Set git-info parameters.
+  zstyle ':prezto:module:git:info' verbose 'yes'
+  zstyle ':prezto:module:git:info:branch' format "${_prompt_skwp_colors[1]}%b%f"
+  zstyle ':prezto:module:git:info:added' format "${_prompt_skwp_colors[5]}●%f"
+  zstyle ':prezto:module:git:info:deleted' format "${_prompt_skwp_colors[2]}●%f"
+  zstyle ':prezto:module:git:info:modified' format "${_prompt_skwp_colors[4]}●%f"
+  zstyle ':prezto:module:git:info:untracked' format "${_prompt_skwp_colors[3]}●%f"
+  zstyle ':prezto:module:git:info:keys' format 'prompt' '(%b%d%a%m%u)'
+
+  # Set ruby-info parameters.
+  zstyle ':prezto:module:ruby:info:version' format '[%v]'
+
+  # Define prompts.
+  PROMPT="${_prompt_skwp_colors[3]}%n%f@${_prompt_skwp_colors[2]}%m%f ${_prompt_skwp_colors[5]}%~%f "'$git_info[prompt]'"$ "
+  RPROMPT='%F{blue}${ruby_info[version]}'
+}
+
+prompt_skwp_setup "$@"

modules/prompt/functions/prompt_smiley_setup

@@ -0,0 +1,65 @@
+#
+# A simple theme that displays:
+#   - Python virtual environment.
+#   - Git branch.
+#   - Git state.
+#   - Last command exit state (smiley/X).
+#
+# Authors:
+#   Nadav Shatz <nadavshatz@gmail.com>
+#
+# Screenshots:
+#   http://i.imgur.com/ijycV6n.png
+#
+
+# Load dependencies.
+pmodload 'helper'
+
+function prompt_smiley_precmd {
+  unsetopt XTRACE KSH_ARRAYS
+
+  # Get Git repository information.
+  if (( $+functions[git-info] )); then
+    git-info
+  fi
+
+  # Get Python environment information.
+  if (( $+functions[python-info] )); then
+    python-info
+  fi
+
+  # Get Ruby version information.
+  if (( $+functions[ruby-info] )); then
+    ruby-info
+  fi
+}
+
+function prompt_smiley_setup {
+  unsetopt XTRACE KSH_ARRAYS
+  prompt_opts=(percent subst)
+
+  # Add hook for calling git-info before each command.
+  add-zsh-hook precmd prompt_smiley_precmd
+
+  # Set editor-info parameters.
+  zstyle ':prezto:module:editor:info:completing' format '%B%F{red}...%f%b'
+
+  # Set python-info parameters.
+  zstyle ':prezto:module:python:info:virtualenv' format '%F{yellow}[%v]%f '
+
+  # Set ruby-info parameters.
+  zstyle ':prezto:module:ruby:info:version' format '%F{yellow}[%v]%f '
+
+  # Set git-info parameters.
+  zstyle ':prezto:module:git:info' verbose 'yes'
+  zstyle ':prezto:module:git:info:branch' format '%F{blue}%b%f'
+  zstyle ':prezto:module:git:info:dirty' format '%%B%F{red} ±%f%%b'
+  zstyle ':prezto:module:git:info:keys' format 'prompt' '(%b%D)'
+
+  # Define prompts.
+  PROMPT='$python_info[virtualenv]$ruby_info[version]${git_info[prompt]} %B%c%b %(?:%F{green}ツ%f:%F{red}✖%f) '
+  RPROMPT='${editor_info[overwrite]}${VIM:+" %B%F{green}V%f%b"}'
+  SPROMPT='zsh: correct %F{red}%R%f to %F{green}%r%f [nyae]? '
+}
+
+prompt_smiley_setup "$@"

modules/prompt/functions/prompt_sorin_setup

@@ -5,7 +5,7 @@
 #   Sorin Ionescu <sorin.ionescu@gmail.com>
 #
 # Screenshots:
-#   http://i.imgur.com/nBEEZ.png
+#   http://i.imgur.com/AzjmpwM.png
 #
 
 # Load dependencies.
@@ -72,8 +72,8 @@ function prompt_sorin_setup {
     'rprompt' '%A%B%S%a%d%m%r%U%u'
 
   # Define prompts.
-  PROMPT='%F{cyan}${_prompt_sorin_pwd}%f${git_info:+${(e)git_info[prompt]}}%(!. %B%F{red}#%f%b.)${editor_info[keymap]} '
+  PROMPT='${SSH_TTY:+"%F{red}%n%f@%F{yellow}%m%f "}%F{cyan}${_prompt_sorin_pwd}%f${git_info:+${(e)git_info[prompt]}}%(!. %B%F{red}#%f%b.)${editor_info[keymap]} '
-  RPROMPT='${editor_info[overwrite]}%(?:: %F{red}⏎%f)${VIM:+" %B%F{green}V%f%b"}${git_info[rprompt]}'
+  RPROMPT='${editor_info[overwrite]}%(?:: %F{red}⏎%f)${VIM:+" %B%F{green}V%f%b"}${INSIDE_EMACS:+" %B%F{green}E%f%b"}${git_info[rprompt]}'
   SPROMPT='zsh: correct %F{red}%R%f to %F{green}%r%f [nyae]? '
 }
 

modules/prompt/init.zsh

@@ -10,9 +10,9 @@ autoload -Uz promptinit && promptinit
 
 # Load the prompt theme.
 zstyle -a ':prezto:module:prompt' theme 'prompt_argv'
-if (( $#prompt_argv > 0 )); then
+if [[ "$TERM" == (dumb|linux|*bsd*) ]] || (( $#prompt_argv < 1 )); then
-  prompt "$prompt_argv[@]"
-else
   prompt 'off'
+else
+  prompt "$prompt_argv[@]"
 fi
 unset prompt_argv

modules/ruby/init.zsh

@@ -28,6 +28,9 @@ elif (( $+commands[chruby-exec] )); then
   source "${commands[chruby-exec]:h:h}/share/chruby/chruby.sh"
   if zstyle -t ':prezto:module:ruby:chruby' auto-switch; then
     source "${commands[chruby-exec]:h:h}/share/chruby/auto.sh"
+
+    # If a default Ruby is set, switch to it.
+    chruby_auto
   fi
 
 # Prepend local gems bin directories to PATH.

modules/ssh/README.md

@@ -4,7 +4,8 @@ SSH
 Provides for an easier use of [SSH][1] by setting up [ssh-agent][2].
 
 This module is disabled on Mac OS X due to custom Apple SSH support rendering it
-unnecessary.
+unnecessary. Use `ssh-add -K` to store identities in Keychain; they will be
+added to `ssh-agent` automatically and persist between reboots.
 
 Settings
 --------

runcoms/zlogin

@@ -17,7 +17,7 @@
 # Print a random, hopefully interesting, adage.
 if (( $+commands[fortune] )); then
   if [[ -t 0 || -t 1 ]]; then
-    fortune -a
+    fortune -s
     print
   fi
 fi