mirror of
https://github.com/dcarrillo/prezto.git
synced 2024-12-22 23:08:00 +00:00
8ee6634c93
Defining it breaks gems for all users who neither use RVM nor rbenv, but have a different default Ruby version nonetheless. Signed-off-by: Sorin Ionescu <sorin.ionescu@gmail.com>
58 lines
1.4 KiB
Bash
58 lines
1.4 KiB
Bash
#
|
|
# Configures Ruby local gem installation, loads version managers, and defines
|
|
# aliases.
|
|
#
|
|
# Authors: Sorin Ionescu <sorin.ionescu@gmail.com>
|
|
#
|
|
|
|
# Load RVM into the shell session.
|
|
if [[ -s "$HOME/.rvm/scripts/rvm" ]]; then
|
|
# Unset AUTO_NAME_DIRS since auto adding variable-stored paths to ~ list
|
|
# conflicts with RVM.
|
|
unsetopt AUTO_NAME_DIRS
|
|
|
|
# Source RVM.
|
|
source "$HOME/.rvm/scripts/rvm"
|
|
|
|
# Load manually installed rbenv into the shell session.
|
|
elif [[ -s "$HOME/.rbenv/bin/rbenv" ]]; then
|
|
path=("$HOME/.rbenv/bin" $path)
|
|
eval "$(rbenv init - --no-rehash zsh)"
|
|
|
|
# Load package manager installed rbenv into the shell session.
|
|
elif (( $+commands[rbenv] )); then
|
|
eval "$(rbenv init - --no-rehash zsh)"
|
|
|
|
# Prepend local gems bin directories to PATH.
|
|
else
|
|
path=($HOME/.gem/ruby/*/bin(N) $path)
|
|
fi
|
|
|
|
# Return if requirements are not found.
|
|
if (( ! $+commands[ruby] && ! ( $+commands[rvm] || $+commands[rbenv] ) )); then
|
|
return 1
|
|
fi
|
|
|
|
#
|
|
# Aliases
|
|
#
|
|
|
|
# General
|
|
alias rb='ruby'
|
|
|
|
# Bundler
|
|
if (( $+commands[bundle] )); then
|
|
alias rbb='bundle'
|
|
alias rbbe='rbb exec'
|
|
alias rbbi='rbb install --path vendor/bundle'
|
|
alias rbbl='rbb list'
|
|
alias rbbo='rbb open'
|
|
alias rbbp='rbb package'
|
|
alias rbbu='rbb update'
|
|
alias rbbI='rbbi \
|
|
&& rbb package \
|
|
&& print .bundle >>! .gitignore \
|
|
&& print vendor/bundle >>! .gitignore \
|
|
&& print vendor/cache >>! .gitignore'
|
|
fi
|