mirror of
https://github.com/dcarrillo/prezto.git
synced 2024-12-23 01:17:59 +00:00
e26387656d
If chruby was installed using default way, most likely chruby and auto-switching will be already sourced (at least on most Linuxes).
75 lines
1.9 KiB
Bash
75 lines
1.9 KiB
Bash
#
|
|
# Configures Ruby local gem installation, loads version managers, and defines
|
|
# aliases.
|
|
#
|
|
# Authors: Sorin Ionescu <sorin.ionescu@gmail.com>
|
|
#
|
|
|
|
# Load RVM into the shell session.
|
|
if [[ -s "$HOME/.rvm/scripts/rvm" ]]; then
|
|
# Unset AUTO_NAME_DIRS since auto adding variable-stored paths to ~ list
|
|
# conflicts with RVM.
|
|
unsetopt AUTO_NAME_DIRS
|
|
|
|
# Source RVM.
|
|
source "$HOME/.rvm/scripts/rvm"
|
|
|
|
# Load manually installed rbenv into the shell session.
|
|
elif [[ -s "$HOME/.rbenv/bin/rbenv" ]]; then
|
|
path=("$HOME/.rbenv/bin" $path)
|
|
eval "$(rbenv init - --no-rehash zsh)"
|
|
|
|
# Load package manager installed rbenv into the shell session.
|
|
elif (( $+commands[rbenv] )); then
|
|
eval "$(rbenv init - --no-rehash zsh)"
|
|
|
|
# Load package manager installed chruby into the shell session.
|
|
elif (( $+commands[chruby-exec] )); then
|
|
if (( ! $+functions[chruby] )); then
|
|
source "${commands[chruby-exec]:h:h}/share/chruby/chruby.sh"
|
|
fi
|
|
|
|
if zstyle -t ':prezto:module:ruby:chruby' auto-switch; then
|
|
if (( ! $+functions[chruby_auto] )); then
|
|
source "${commands[chruby-exec]:h:h}/share/chruby/auto.sh"
|
|
fi
|
|
|
|
# If a default Ruby is set, switch to it.
|
|
chruby_auto
|
|
fi
|
|
|
|
# Prepend local gems bin directories to PATH.
|
|
else
|
|
path=($HOME/.gem/ruby/*/bin(N) $path)
|
|
fi
|
|
|
|
# Return if requirements are not found.
|
|
if (( ! $+commands[ruby] && ! ( $+commands[rvm] || $+commands[rbenv] ) )); then
|
|
return 1
|
|
fi
|
|
|
|
#
|
|
# Aliases
|
|
#
|
|
|
|
# General
|
|
alias rb='ruby'
|
|
|
|
# Bundler
|
|
if (( $+commands[bundle] )); then
|
|
alias rbb='bundle'
|
|
alias rbbc='bundle clean'
|
|
alias rbbe='bundle exec'
|
|
alias rbbi='bundle install --path vendor/bundle'
|
|
alias rbbl='bundle list'
|
|
alias rbbo='bundle open'
|
|
alias rbbp='bundle package'
|
|
alias rbbu='bundle update'
|
|
alias rbbI='rbbi \
|
|
&& bundle package \
|
|
&& print .bundle >>! .gitignore \
|
|
&& print vendor/assets >>! .gitignore \
|
|
&& print vendor/bundle >>! .gitignore \
|
|
&& print vendor/cache >>! .gitignore'
|
|
fi
|